Using RSS as a means to create automatic dynamic content with minimal work fascinates me. Most bloggers probably create feeds on a regular basis - most likely at least a Flickr feed, and possibly del.icio.us.

These provide JavaScript services to parse the feed into your site; however, with the prevalence of server-side scripting, why not have fun and parse the feed into your blog yourself?

It's super-simple, and after looking at a couple of references, I parsed my delicious feed into my about page in mere moments (although I could have just as easily put it in a CF blog template). Before I explain the steps, these following references helped me:

• "Parsing RSS Feeds Using ColdFusion" by Domenic Plouffe (http://coldfusion.sys-con.com/read/issue/219.htm) for the CF tags to work with XML.
• If you are unfamiliar with traversing XML, check "A Really, Really, Really Good Introduction to XML" by Tom Myer (www.sitepoint.com/article/really-good-introduction-xml).
• My brilliant brother, who writes at Nazin (www.nazin.com/) and taught me nearly everything I know.

The Quick and Dirty Way
1.  Retrieve the document. Be sure to do this first.

<cfhttp url="http://del.icio.us/rss/myUserName" method="get">

2.  Parse the RSS:

<cfset objRSS = xmlParse(cfhttp.filecontent)>

Obviously, this creates a var named objRSS and fills it with the parsed XML.

3.  Output the list. I simply output the titles and links, so my code appears as follows:

<ul>
<cfloop from="1" step="+1" to="10" index="counter">
<cfset xTitle = objRSS.xmlRoot.xmlChildren[counter + 1]["title"].xmltext>
<cfset xLink = objRSS.xmlRoot.xmlChildren[counter + 1]["link"].xmltext>
    <cfoutput>
      <li><a href="#xLink#">#xTitle#</a></li>
    </cfoutput>
</cfloop>
</ul>

A brief delineation is in order for those new to RSS and ColdFusion.

<cfloop from="1" step="+1" to="10" index="counter">

This will loop from one to 10, incrementing by one, thus, 10 iterations.

<cfset xTitle = objRSS.xmlRoot.xmlChildren[counter + 1]["title"].xmltext>

This sets into a variable named xTitle the text in the "title" tag of our RSS.

• objRSS is the variable holding the parsed RSS.
• xmlRoot, for lack of better explanation, "opens" it up. Really, it's the <RDF> that contains all of the subsequent data inside.
• xmlChildren[counter + 1] is where the fun begins. I say counter + 1 because xmlChildren[1], with delicious, would open <channel>, which merely contains the boring synopsis of the feed. xmlChildren[2] and so forth are the items that I want - my remembered links. Then I specify which element of the child "item" I want by ["title"], remembering quotations, as XML is case sensitive and ColdFusion is not.
• xmltext is a tostring method, of sorts. It grabs the content of said tag.

<cfoutput> <li><a href="#xLink#">#xTitle#</a></li> </cfoutput>

We're outputting what we've stored in the variables, with #s surrounding our variable names because we're mixing variables with attributes and HTML output. Notice that earlier, when mixed with pure ColdFusion (as in the cfloop), these #s were unnecessary, and thus omitted. It still would compile, but we might as well learn it right the first time.

4.  If you want to output the entire feed, change to="10" to to="#ArrayLen(objRSS.xmlRoot.xmlChildren)#". Again, we have #s around ArrayLen. This is because it is an attribute. Remember the #s for attributes and HTML output. Otherwise, lose them.

5.  Test it out and hopefully it works.

The Better Way
As things are, every time a person visits the page, it grabs the RSS document, parses it, and works with it. If this scripting is on every page on your blog, this is unnecessarily taxing to both your server and wherever your RSS document is hosted. del.icio.us, for one, prefers caching, where we take the doc, parse it, and store it for a defined period of time.

1.  If you don't already have a file on your server called "application.cfm", create one.

2.  Add to application.cfm:

<cfapplication name="myApplicationName">

3.  If you worked through the Quick and Dirty Way, erase the lines beginning with cfhttp and the matching parsing cfset. Add to application.cfm:

<cfif Not StructKeyExists(Application,"RefreshDT") or Application.RefreshDT LT Now()>
    <cfhttp url="http://del.icio.us/rss/myUserName" method="get">
    <cfset Application.objRSS=xmlParse(cfhttp.filecontent)>
<cfset Application.RefreshDT = DateAdd("d",1,Now())>
</cfif>
<cfset Variables.objRSS=Application.objRSS>

To be clear, this checks to see whether the application var exists or if the RefreshDT time has passed. If it has expired or does not exist, it pulls the RSS document and creates the application, creating a variable named objRSS and parsing the RSS into it. Then RefreshDT is set using the DateAdd() function. The arguments for DateAdd are ("datepart', units of datepart to add to "date", "date"). Our example adds one day ("d") to Now().

Finally, whether the application had to do these steps or not, it makes a local var called objRSS containing the same data as the application var objRSS. This way, it only pulls and parses the feed once for the life of RefreshDT, which this example set to one day.

That was fun, and hopefully it proved to be helpful as well. Big thanks to Josh for teaching me CF in the first place!

• Desktop Spreadsheet Applications Upgraded to User-friendly Web UI with Minimal work