In my last article we looked at how to sort multidimensional arrays by creating a second single-dimensional array that is used as a key. The focus of this article is how to sort multidimensional arrays by creating a query object that can be sorted in the same way you would an ordered result set from a database. In truth, this article will demonstrate two methods: one for ColdFusion 5.0 and a second, far superior method using the <CFFUNCTION> tag introduced with ColdFusion MX.

The first step is to build a small multidimensional array. The example code below shows daily sales for a fruit stand:

<cfset Session.masDailySales = arraynew(2)>
<cfset Session.masDailySales[1][1] = "Apples">
<cfset Session.masDailySales[1][2] = "1">
<cfset Session.masDailySales[1][3] = "9.95">
<cfset Session.masDailySales[1][4] = "Michael">
<cfset Session.masDailySales[1][5] = "Cash">
<cfset Session.masDailySales[2][1] = "Oranges">
<cfset Session.masDailySales[2][2] = "1">
<cfset Session.masDailySales[2][3] = "6.95">
<cfset Session.masDailySales[2][4] = "Joanne">
<cfset Session.masDailySales[2][5] = "Check">
<cfset Session.masDailySales[3][1] = "Peaches">
<cfset Session.masDailySales[3][2] = "4">
<cfset Session.masDailySales[3][3] = "8.95">
<cfset Session.masDailySales[3][4] = "Michael">
<cfset Session.masDailySales[3][5] = "Credit">

For each of the two new methods three variables will need to be created:

<cfset colArray = session.masdailysales>
<cfset colNames = "product,quantity,price,name,type">
<cfset colSort = #sort_column#>

The colArray variable will be a local copy of the original array, colNames will be the field names assigned to each column of the table being created, and colSort (passed as a URL variable, named sort_column, from the column header hyperlinks described below) will be the number of the column that the completed table will be sorted on.

Defining the colSort Variable
Each of the column titles is displayed to the user as a hyperlink. The hyperlinks will each call the page again and will pass the column number as sort_column. The code below shows how it will default to one (1). Each time the page is called it looks for this information and sets the sort_column URL parameter that will be used to create the colSort variable.

As an example, the title for the Quantity would be coded as:

<a href="MultArraySort.cfm?&sort_column=2">Quantity</a>

When the page is reloaded, the following code will set the column number that is to be sorted. The IsNumeric() function is used to ensure that a numeric value is used. This defaults to 1 if not defined, blank, less than zero, greater than the number of columns (5 in this example), or non-numeric.

<cfif IsDefined("url.sort_column") AND IsNumeric(url.sort_column) AND
url.sort_column GT 0 and
url.sort_column LT 5>
<cfset sort_column = url.sort_column>
<cfelse>
<cfset sort_column = 1>
</cfif>

ColdFusion 5 Coding
Using the string colNames, an array will be created that contains the field names for each of the elements of the original array:

<cfset s_order = arraynew(1)>
<cfloop from="1" to="#ListLen(colNames)#" index="i">
<cfset s_order[i] = ListGetAt(colNames,i)>
</cfloop>

This coding will create the array to the right.

The first step in querying arrays is creating a query object. Query objects are data structures that hold data, such as the information from our original array. Using the QueryNew(), QueryAddRow(), and QuerySetCell() functions, the following code illustrates how to create a query object called tempquery:

<cfset tempquery = QueryNew(#colNames#)>
<cfset qRow = QueryAddRow(tempquery, #ArrayLen(colArray)#)>
<cfloop from="1" to="#ArrayLen(colArray)#"
index="i">
<cfloop from="1" to="#ArrayLen(s_order)#" index="j">
<cfset temp = QuerySetCell(tempquery,
"#s_order[j]#",
colArray[i][j], i)>
</cfloop>
</cfloop>

The parameter for the QueryNew() function is the string colNames. This string contains the equivalent of field names in a database table or column headers. Next we’ll add the same number of rows to the tempquery array as there are in the original array. The QueryAddRow() function is used to add these rows with tempquery and the length of the original array used as parameters.

Using a nested loop sequence and the QuerySetCell() function, the tempquery array is populated with the data from the original array, only now we have a query object:

 

The final step is executing a <CFQUERY>, selecting from tempquery and setting the order to the column specified by the colSort variable:

<cfquery dbtype="query" name="sortquery">
select * from tempquery
order by #s_order[colSort]#
</cfquery>

Less code is required, execution time is slightly faster, and you get the same results as you would using the coding in my previous article. With a little experimentation this code can be easily converted to a custom tag.

ColdFusion MX Coding
ColdFusion MX introduced <CFFUNCTION>, making it no longer necessary to use <CFSCRIPT>. With <CFFUNCTION> you can now create user-defined functions that use ColdFusion tags in their body, including <CFQUERY> and <CFSTOREDPROC>.

By changing the local variables to parameters and using the sortquery object as a return value, the following code will create a custom function that can be utilized in any ColdFusion MX application. The coding is shown below:

<cffunction name="MDArraySort" Returntype="query">
<!--- Create an arguments collection for arguments passed to function colArray – array being sorted colNames – column/field names for the table being created colSort – which column to sort on --->
<cfargument name="colArray" type="array" required="true">
<cfargument name="colNames" type="string" required="true">
<cfargument name="colSort" type="string" required="true">
<!--- Declare variable collection used in function as local --->
<cfset var s_order = arraynew(1)>
<cfset var tempquery = "">
<cfset var qRow = "">
<cfset var temp = "">
<!--- Create array that contains the column/field names --->
<cfloop from="1" to="#ListLen(arguments.colNames)#" index="i">
<cfset s_order[i] = ListGetAt(arguments.colNames,i)>
</cfloop>
<cfset tempquery = querynew(#arguments.colNames#)>
<cfset qRow = QueryAddRow(tempquery,
#ArrayLen(arguments.colArray)#)>
<!--- Populate the query table --->
<cfloop from="1" to="#arraylen(arguments.colArray)#" index="i">
<cfloop from="1" to="#arraylen(s_order)#" index="j">
<cfset temp = QuerySetCell(tempquery, "#s_order[j]#",
arguments.colArray[i][j], i)>
</cfloop>
</cfloop>
<!--- perform a select that sorts the new table --->
<cfquery dbtype="query" name="sortquery">
select * from tempquery
order by #s_order[arguments.colSort]#
</cfquery>
<cfreturn sortquery>
</cffunction>

With the function created and made available to all applications, the following code will create a query object that can be used to display the information to the user, in the order they select. <cfset t1 = MDArraySort(session.masdailysales,"product,quantity,price, name,type","#colOrder#")>

Far superior to the previously described routines, the ColdFusion MX solution is generic, and can be utilized in any ColdFusion MX application without modification.

Conclusion
As shown in these two articles, working with arrays can add flexibility, increase the speed of a dynamic Web page by reducing the number of calls to a data source, add power to your Web application, and ultimately make the end user of your Web application very happy. In closing, remember, when old man Murphy comes to visit, always give him a warm welcome and learn from the lessons he strives to teach.